ΠΡΟΓΡΑΜΜΑ ΠΕΡΙΠΟΙΗΣΗ_ΝΥΧΙΩΝ
! Ερώτημα 4.1: Δηλώσεις μεταβλητών
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ: ΠΛ, ΧΡ, ΕΣΟΔΑ_Π, ΕΣΟΔΑ_ΣΥΝ, ΜΙΝ_ΧΡ
  ΠΡΑΓΜΑΤΙΚΕΣ: ΠΟΣΟΣΤΟ_Π
  ΧΑΡΑΚΤΗΡΕΣ: ΟΝΟΜΑ, ΕΙΔ, ΕΙΔΟΣ, ΜΙΝ_ΟΝΟΜΑ
ΑΡΧΗ
  ΕΣΟΔΑ_ΣΥΝ <- 0   ! 4.3 : συνολικά εσοδα  τριμήνου
  ΕΣΟΔΑ_Π <- 0     ! 4.3 : εσοδα  από Πεντικιούρ
  ΜΙΝ_ΧΡ <- 10000  ! 4.3 :ελάχιστη χρεωση  τριμήνου
! 4.1 : Εισαγωγή δεδομενων
  ΓΡΑΨΕ 'Δώσε το ονοματεπώνυμο του 1ου πελάτη:'
  ΔΙΑΒΑΣΕ ΟΝΟΜΑ
  ΟΣΟ ΟΝΟΜΑ <> 'ΤΕΛΟΣ' ΕΠΑΝΑΛΑΒΕ
    ΓΡΑΨΕ 'Δώσε το είδος  της περιποίηςησ (Μ ή Π):'
    ΔΙΑΒΑΣΕ ΕΙΔ
    ΓΡΑΨΕ 'Δώσε πλήθος  περιποιήσεων τριμήνου:'
    ΔΙΑΒΑΣΕ ΠΛ
! 4.2 Υπολογισμός χρεωσης τριμήνου για πελάτη
    ΑΝ ΕΙΔ = 'Μ' ΤΟΤΕ
      ΕΠΙΛΕΞΕ ΠΛ
        ΠΕΡΙΠΤΩΣΗ <= 2
          ΧΡ <- ΠΛ* 18
        ΠΕΡΙΠΤΩΣΗ <= 5
          ΧΡ <- 2* 18 + (ΠΛ - 2)*16
        ΠΕΡΙΠΤΩΣΗ ΑΛΛΙΩΣ
          ΧΡ <- 2* 18 + 3* 16 + (ΠΛ - 5)* 14
      ΤΕΛΟΣ_ΕΠΙΛΟΓΩΝ
    ΑΛΛΙΩΣ_ΑΝ ΕΙΔ = 'Π' ΤΟΤΕ
      ΕΠΙΛΕΞΕ ΠΛ
        ΠΕΡΙΠΤΩΣΗ <= 2
          ΧΡ <- ΠΛ* 20
        ΠΕΡΙΠΤΩΣΗ <= 5
          ΧΡ <- 2* 20 + (ΠΛ - 2)* 17
        ΠΕΡΙΠΤΩΣΗ ΑΛΛΙΩΣ
          ΧΡ <- 2* 20 + 3* 17 + (ΠΛ - 5)* 15
      ΤΕΛΟΣ_ΕΠΙΛΟΓΩΝ
      ΕΣΟΔΑ_Π <- ΕΣΟΔΑ_Π + ΧΡ                  ! 4.3 συνολο εσοδα απο πεντικιουρ
    ΤΕΛΟΣ_ΑΝ
    ΓΡΑΨΕ 'Χρεωση τριμήνου (σε €) για ', ΟΝΟΜΑ, ':', ΧΡ
    ΕΣΟΔΑ_ΣΥΝ <- ΕΣΟΔΑ_ΣΥΝ + ΧΡ                  ! 4.3 ενημερωση εσόδων τριμήνου
    ΑΝ ΧΡ < ΜΙΝ_ΧΡ ΤΟΤΕ                           ! 4.3 Ελάχιστη χρέωση τριμήνου
      ΜΙΝ_ΧΡ <- ΧΡ
      ΜΙΝ_ΟΝΟΜΑ <- ΟΝΟΜΑ
      ΕΙΔΟΣ <- ΕΙΔ
    ΤΕΛΟΣ_ΑΝ
    ΓΡΑΨΕ 'Δώσε επομενο πελάτη ή ΤΕΛΟΣ για τερματισμό:'
    ΔΙΑΒΑΣΕ ΟΝΟΜΑ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
! 4.3 : Εμφάνιση  ποσοστου εσοδων από πεντικιουρ
  ΠΟΣΟΣΤΟ_Π <- ΕΣΟΔΑ_Π/ΕΣΟΔΑ_ΣΥΝ* 100
  ΓΡΑΨΕ 'Ποσοστό (%) εσοδων απο πεντικιουρ:', ΠΟΣΟΣΤΟ_Π
!4.3 Εμφάνιση πελάτη που πλήρωσε τα λιγότερα και σε  ποιο  ειδος
  ΑΝ ΕΙΔΟΣ = 'Μ' ΤΟΤΕ
    ΕΙΔΟΣ <- 'ΜΑΝΙΚΙΟΥΡ'
  ΑΛΛΙΩΣ
    ΕΙΔΟΣ <- 'ΠΕΝΤΙΚΙΟΥΡ'
  ΤΕΛΟΣ_ΑΝ
  ΓΡΑΨΕ 'Πελάτης με την ελάχιστη χρεωση:', ΜΙΝ_ΟΝΟΜΑ, ' ΣΕ ', ΕΙΔΟΣ
ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ