ΠΡΟΓΡΑΜΜΑ Αραιός_Αναζήτηση_simple
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ: i, j, k, x, Π[5, 5], Α[15], L, M, result
  ΛΟΓΙΚΕΣ: τέλος
ΑΡΧΗ
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 5 ! i=γραμμή
    ΓΙΑ j ΑΠΟ 1 ΜΕΧΡΙ 5 ! j=στήλη
      Π[i, j] <- 0
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 5 ! Γέμισμα του πίνακα Π
    ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
      ΔΙΑΒΑΣΕ j
    ΜΕΧΡΙΣ_ΟΤΟΥ j >= 1 ΚΑΙ j <= 5 ΚΑΙ j <> i
    ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
      ΔΙΑΒΑΣΕ x ! x=τιμή στοιχείου (<>0)
    ΜΕΧΡΙΣ_ΟΤΟΥ x <> 0
    Π[i, j] <- x
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  k <- 1 ! k=θέση στοιχείου
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 5 ! Δημιουργία του πίνακα Α
    ΓΙΑ j ΑΠΟ 1 ΜΕΧΡΙ 5
      ΑΝ Π[i, j] <> 0 ΤΟΤΕ
        Α[k] <- i
        Α[k + 1] <- j
        Α[k + 2] <- Π[i, j] 
        k <- k + 3
      ΤΕΛΟΣ_ΑΝ
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 5
    ΓΙΑ j ΑΠΟ 1 ΜΕΧΡΙ 5
      ΓΡΑΨΕ Π[i, j] 
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 15
    ΓΡΑΨΕ Α[i], '  '
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ! ------------------------
  ! ΤΕΤΡΑΔΙΟ ΜΑΘΗΤΗ: ΚΕΦΑΛΑΙΟ 3 - ΠΑΡΑΔΕΙΓΜΑ 5 - Αναζήτηση στοιχείου
  ΔΙΑΒΑΣΕ L, M ! Ζητείται η γραμμή L και η στήλη Μ του πίνακα Π
  τέλος <- ΨΕΥΔΗΣ
  k <- 0                   !k <- 1
  ΟΣΟ τέλος = ΨΕΥΔΗΣ ΕΠΑΝΑΛΑΒΕ
    i <- Α[3*k + 1]        !i <- Α[k]
    j <- Α[3*k + 2]        !j <- Α[k+1]
    ΑΝ i = L ΚΑΙ j = M ΤΟΤΕ
      result <- Α[3*k + 3] !result <- Α[k+2]
      τέλος <- ΑΛΗΘΗΣ
    ΑΛΛΙΩΣ_ΑΝ i > L Η (i = L ΚΑΙ j > M) ΤΟΤΕ ! Το στοιχείο δεν βρέθηκε
      result <- 0
      τέλος <- ΑΛΗΘΗΣ
    ΑΛΛΙΩΣ                 ! Συνεχίζουμε στο επόμενο στοιχείο
      k <- k + 1           !k <- k+3
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΓΡΑΨΕ result
ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ