ΠΡΟΓΡΑΜΜΑ ΓΕΛ2014Θ4_3ος_τρόπος
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ: i, j, ΕΠ[10, 28], ΣΕΠ[4], Σ, πλ, ΟΛΟΙ, θ, π, τ, max
  ΧΑΡΑΚΤΗΡΕΣ: ΟΝ[10], όνομα
ΑΡΧΗ

!Δ1
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 10
    ΔΙΑΒΑΣΕ ΟΝ[i] 
    ΓΙΑ j ΑΠΟ 1 ΜΕΧΡΙ 28
      ΔΙΑΒΑΣΕ ΕΠ[i, j] 
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

!Δ2
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 10
    Σ <- 0
    ΓΙΑ j ΑΠΟ 1 ΜΕΧΡΙ 28
      Σ <- Σ + ΕΠ[i, j] 
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
    ΓΡΑΨΕ ΟΝ[i], Σ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

!Δ3
  ΟΛΟΙ <- 0
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 10
    πλ <- 0
    ΓΙΑ j ΑΠΟ 1 ΜΕΧΡΙ 28
      ΑΝ ΕΠ[i, j] > 500 ΤΟΤΕ
        πλ <- πλ + 1
      ΤΕΛΟΣ_ΑΝ
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
    ΑΝ πλ = 28 ΤΟΤΕ
      ΓΡΑΨΕ ΟΝ[i] 
      ΟΛΟΙ <- ΟΛΟΙ + 1
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  ΑΝ ΟΛΟΙ = 0 ΤΟΤΕ
    ΓΡΑΨΕ "δεν υπάρχει"
  ΤΕΛΟΣ_ΑΝ

!Δ4
  ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
    ΔΙΑΒΑΣΕ όνομα
    θ <- 0
    ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 10
      ΑΝ ΟΝ[i] = όνομα ΤΟΤΕ
        θ <- i
      ΤΕΛΟΣ_ΑΝ
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΜΕΧΡΙΣ_ΟΤΟΥ θ <> 0

 ! Δημιουργία πίνακα εβδομαδιαίων συνόλων

  π <- 1      ! 1η ημέρα της εβδομάδας
  τ <- 7      ! 7η (τελευταία) ημέρα της εβδομάδας

  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 4    ! Για κάθε μία εβδομάδα
    ΣΕΠ[i] <- 0
    ΓΙΑ j ΑΠΟ π ΜΕΧΡΙ τ  ! Απο την 1η μέχρι την 7η ημέρα
      ΣΕΠ[i] <- ΣΕΠ[i] + ΕΠ[θ, j] 
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
    π <- π + 7           ! π = 1, 8, 15, 22
    τ <- τ + 7           ! τ = 7, 14, 21, 28
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  max <- ΣΕΠ[1] 
  ΓΙΑ i ΑΠΟ 2 ΜΕΧΡΙ 4
    ΑΝ ΣΕΠ[i] > max ΤΟΤΕ
      max <- ΣΕΠ[i] 
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 4
    ΑΝ ΣΕΠ[i] = max ΤΟΤΕ
      ΓΡΑΨΕ i
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ