ΠΡΟΓΡΑΜΜΑ Ώθηση_Απώθηση
ΣΤΑΘΕΡΕΣ
  πλήθος = 3
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ: top, i
  ΧΑΡΑΚΤΗΡΕΣ: Α[πλήθος], στοιχείο, πλήκτρο, συνέχεια
  ΛΟΓΙΚΕΣ: Υπερχείλιση
ΑΡΧΗ
  ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
    ΓΡΑΨΕ "ΏΘΗΣΗ & ΑΠΩΘΗΣΗ ΣΕ ΣΤΟΙΒΑ ", πλήθος, " ΣΤΟΙΧΕΙΩΝ"
    Υπερχείλιση <- ΨΕΥΔΗΣ
    top <- 0
    ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
      ΓΡΑΨΕ "Δώστε στοιχείο (κείμενο) για να εισαχθεί στη στοίβα [Enter για διακοπή] : "
      ΔΙΑΒΑΣΕ στοιχείο
      ΑΝ top <= πλήθος ΚΑΙ στοιχείο <> "" ΤΟΤΕ
        top <- top + 1
        ΑΝ top > πλήθος ΤΟΤΕ
          ΓΡΑΨΕ
          ΓΡΑΨΕ "Υπερχείλιση στοίβας"
          top <- top - 1
          Υπερχείλιση <- ΑΛΗΘΗΣ
        ΑΛΛΙΩΣ
          Α[top] <- στοιχείο
          ΓΡΑΨΕ "Ωθήθηκε το ", top, "ο στοιχείο : ", Α[top] 
        ΤΕΛΟΣ_ΑΝ
      ΤΕΛΟΣ_ΑΝ
    ΜΕΧΡΙΣ_ΟΤΟΥ στοιχείο = "" Η Υπερχείλιση = ΑΛΗΘΗΣ
    ΓΡΑΨΕ "Η στοίβα περιέχει ", top, " στοιχεία :   "
    ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ top
      ΓΡΑΨΕ Α[i], "(", i, "ο)   "
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
    ΓΡΑΨΕ
    ΓΡΑΨΕ
    ΓΡΑΨΕ "Η τιμή του δείκτη top είναι : ", top
    ΓΡΑΨΕ "Απώθηση Στοιχείου ; [<Ν> για συνέχεια, <Enter> για διακοπή] "
    ΔΙΑΒΑΣΕ πλήκτρο
    ΟΣΟ πλήκτρο <> "" ΚΑΙ top >= 0 ΕΠΑΝΑΛΑΒΕ
      ΑΝ top = 0 ΤΟΤΕ
        ΓΡΑΨΕ "Υποχείλιση στοίβας"
        πλήκτρο <- ""
      ΑΛΛΙΩΣ
        ΓΡΑΨΕ "Απωθήθηκε το ", top, "ο στοιχείο : ", Α[top] 
        Α[top] <- " "
        top <- top - 1
        ΓΡΑΨΕ "Απώθηση Στοιχείου ; [<Ν> για συνέχεια, <Enter> για διακοπή] "
        ΔΙΑΒΑΣΕ πλήκτρο
      ΤΕΛΟΣ_ΑΝ
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
    ΓΡΑΨΕ "Η τιμή του δείκτη top είναι : ", top
    ΑΝ top = 0 ΤΟΤΕ
      ΓΡΑΨΕ "Η στοίβα είναι άδεια "
    ΑΛΛΙΩΣ
      ΓΡΑΨΕ "Η στοίβα περιέχει ", top, " στοιχεία :   "
      ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ top
        ΓΡΑΨΕ Α[i], "(", i, "ο)   "
      ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
    ΤΕΛΟΣ_ΑΝ
    ΓΡΑΨΕ
    ΓΡΑΨΕ "Επανάληψη ; [<Ν> για συνέχεια, <Enter> για διακοπή] "
    ΔΙΑΒΑΣΕ συνέχεια
  ΜΕΧΡΙΣ_ΟΤΟΥ συνέχεια = ""
ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ